if MsgBox("Attention, vous allez modifier les bases de registre. Voulez vous continuer ?", 4, "le son de windows au démarrage") = 7 Then wscript.quit

'vérification de la configuration (existence des clés)
Set ssh = WScript.CreateObject("WScript.Shell")
debreg="HKEY_CURRENT_USER\AppEvents\Schemes\Apps\.Default\SystemStart\"
cle1=debreg & ".Current\"
cle2=debreg & ".Default\"
on error resume next
val1= ssh.RegRead(cle1)
val2= ssh.RegRead(cle2)
on error goto 0
if val1 & val2="" then '*************************************************
msgbox "configuration non compatible"

'choix du fichier son
else '*************************************************
fichson=inputbox("tapez l'adresse du fichier son","le son de Windows au démarrage","C:\WINDOWS\media\The Microsoft Sound.wav")
if fichson="" then Wscript.Quit

'sauvegarder les infos de la base de registre
Set fs=CreateObject("Scripting.FileSystemObject")
if fs.fileexists("c:\restaurer_sons_demarrage_win.txt") then
msgbox "le fichier c:\restaurer_sons_demarrage_win.txt existe déjà et n'a pas été modifié"
else
Set fich = fs.OpenTextFile("c:\restaurer_sons_demarrage_win.txt", 2, true)
fich.WriteLine "Les bases de registre ont été modifiées"
fich.WriteLine "Pour restaurer le son émis par Windows au moment du démarrage,"
fich.WriteLine "il faut redonner leur valeurs initiales à deux clés de la base de registres :"
fich.WriteLine val1 & " pour la clé : " & cle1
fich.WriteLine val2 & " pour la clé : " & cle2
fich.close
end if
Set fs=Nothing
Set fich=nothing

'modifier les clés de la base de registres
ssh.RegWrite cle1,fichson
ssh.RegWrite cle2,fichson

ssh.run "explorer c:\restaurer_sons_demarrage_win.txt"
end if '*************************************************
Set ssh=nothing